Continue to Site

Welcome to our site!

Electro Tech is an online community (with over 170,000 members) who enjoy talking about and building electronic circuits, projects and gadgets. To participate you need to register. Registration is free. Click here to register now.

  • Welcome to our site! Electro Tech is an online community (with over 170,000 members) who enjoy talking about and building electronic circuits, projects and gadgets. To participate you need to register. Registration is free. Click here to register now.

Import 3rd party simulation into LTSpice

Status
Not open for further replies.
I'm using LTSpice XVII and having trouble importing the Fairchild simulation library for the FQP30N06.lib
The FQP30N06.lib file is in the folder C:\Users\Mike\Documents\LTspiceXVII\Models and I have tried these two methods:
  • .inc C:\Users\Mike\Documents\LTspiceXVII\Models\FQP30N06.lib
  • .lib C:\Users\Mike\Documents\LTspiceXVII\Models\FQP30N06.lib
Neither one works. and the error is that it can't find the definition of model "fqp30n06"

Here are the contents of the .lib file:
Code:
*$
**************** Power Discrete MOSFET Electrical Circuit Model *****************
** Product Name: FQP30N06
** 60V, 30A N-Channel MOSFET and TO-220
** Model Type: BSIM3V3
**-------------------------------------------------------------------------------
.SUBCKT FQP30N06 2 1 3  
*Nom Temp=25 deg C
Dbody 7 5    DbodyMOD
Dbreak 5 11  DbreakMOD
Ebreak 11 7 17 7 66
Lgate 1 9    1.125e-9
Ldrain 2 5   1.125e-9
Lsource 3 7  8.431e-10
RLgate 1 9   11.25
RLdrain 2 5  11.25
RLsource 3 7 8.431
Rgate 9 6    0.5
It 7 17      1
Rbreak 17 7  RbreakMOD 1
.MODEL RbreakMOD RES (TC1=1.08e-3 TC2=-1.25e-6)
.MODEL DbodyMOD D (IS=1.45e-12 N=1       RS=2.62e-3   TRS1=1.02e-3   TRS2=1e-6
+ CJO=1.25e-9      M=0.36      VJ=0.38   TT=4.05e-8   XTI=3          EG=1.17)
.MODEL DbreakMOD D (RS=100e-3 TRS1=1e-3 TRS2=1.0e-6)
Rdrain 5 16 RdrainMOD 0.031
.MODEL RdrainMOD RES (TC1=7.85e-3 TC2=3.06e-6)
M_BSIM3 16 6 7 7 Bsim3 W=1.35 L=2.0e-6 NRS=1
.MODEL Bsim3 NMOS (LEVEL=7 VERSION=3.1 MOBMOD=3 CAPMOD=2 PARAMCHK=1 NQSMOD=0
+ TOX=780e-10      XJ=1.4e-6      NCH=1.63e17
+ U0=700           VSAT=1.0e5     DROUT=1.0
+ DELTA=0.10       PSCBE2=0       RSH=3.02e-4
+ VTH0=3.65        VOFF=-0.1      NFACTOR=1.1
+ LINT=3.88e-7     DLC=3.88e-7    FC=0.5
+ CGSO=1.2e-15     CGSL=0         CGDO=1.0e-14
+ CGDL=6.06e-10    CJ=0           CF=0  
+ CKAPPA=0.2       KT1=-1.58      KT2=0
+ UA1=-1.08e-9     NJ=10)
.ENDS
*$
*************** Power Discrete MOSFET Thermal Model ********************
** Package: TO-220
**----------------------------------------------------------------------
.SUBCKT FQP30N06_THERMAL TH TL
CTHERM1 TH 6 1.04e-5
CTHERM2 6 5  1.84e-3
CTHERM3 5 4  8.52e-3
CTHERM4 4 3  3.04e-2
CTHERM5 3 2  7.22e-2
CTHERM6 2 TL 2.42e-1
RTHERM1 TH 6 1.08e-2
RTHERM2 6 5  4.91e-2
RTHERM3 5 4  8.25e-2
RTHERM4 4 3  3.28e-1
RTHERM5 3 2  4.95e-1
RTHERM6 2 TL 9.27e-1
.ENDS FQP30N06_THERMAL
**---------------------------------------------------------------------
** Creation: Dec.-04-2015   Rev: 1.0
** Fairchild Semiconductor

Any help will be appreciated.
 
LTS expects your model file to be in the ...Documents\LTspiceXVII\lib\sub folder and your symbol file to be in the ...Documents\LTspiceXVII\lib\sym folder.
 
I moved the FQP30N06.lib file to the LTspiceXVII\lib\sub folder. I don't have the symbol file and am using the standard nmos symbol. That didn't get rid of the error.
Seems like there should be an easy way to import 3rd party models.
 
am using the standard nmos symbol
In that case perhaps LTS looks in the standard.mos file and fails to find the model? (I've never tried adding a mosfet model as a sub-circuit.)
 
In that case perhaps LTS looks in the standard.mos file and fails to find the model? (I've never tried adding a mosfet model as a sub-circuit.)
Yes, I found the FQP30N06.lib file at Fairchild and OnSemi but they are identical. They are SUBCKT files and that appears to be the problem. There is no actual .Model FQP30N06 line in those files. Guess I'm stuck here unless someone comes up with a way to add that device to LTSpice XVII.
 
try this:
http://www.simonbramble.co.uk/lt_spice/ltspice_lt_spice_tutorial_4.htm

I never mess with the internal libraries of LTspice. Then if I reinstall LTspice, none of my imported models get over written.

4 things to note:
Save the model into the same directory as the circuit you are trying to simulate
If using a SUBCKT model, you need to do <CTRL> right click over the component and change the Prefix to X
Use a .include statement and copy and paste the file name into the .include statement. The .include statement must exactly match the filename
Do <CTRL> Right Click again and change Value, in your case, to FQP30N06

It seemed to throw a reaction to the FC term in your model, so I deleted it. It now works. Please see attached

Simon
 

Attachments

  • FQP30N06.txt
    2 KB · Views: 240
  • Draft1.asc
    738 bytes · Views: 213
This sort-of works. I don't think that LTSpice understands the Level7 model:

You will have to use the following symbol file.
 

Attachments

  • FQPtest.asc
    1.8 KB · Views: 200
  • NMOSsub.asy
    663 bytes · Views: 183
Simon, thank you for that post!

Changing the prefix to 'X' and deleting the fc item fixed it for me.

Appreciate the help!
 
Status
Not open for further replies.

Latest threads

New Articles From Microcontroller Tips

Back
Top