Hi Trent,
I get back to this tonight or in the AM...dinner plans.
EDIT:
OK, here is the model, but I don’t know if you have done this before so I’ll give the step-by-step procedure I use to install a .sub style without a symbol file.
1. Open Windows Explorer and open Program Files of the drive in which it is located;
2. Lclick on LCT, then Lclick on LtspiceIV, then Lclick on Lib, then Lclick on Sub;
3. Now create a sub folder “OPAMPS”, but stay in the main .SUB folder;
4. Now locate the .SUB file “opamp” & Rclick on it and open with Notepad;
5. With the file open in Notepad, delete all contents (it will be save as LM324 later);
6. Copy the LM324 file from the source and paste it in the open Notepad app;
7. Now LClick on file and “save as” with type “All Files” & Encoding “ANSI”;
8. Now select the “OPAMPS” folder in the window and type in filename LM324.SUB
9. Now click save.
To test, open your schematic, delete the opamp you are using currently, and go to the toolbar and click on the IC icon and op amps. From there select “opamp2” and place it on the schematic. Place the cursor over the amp and Rclick and a dialog window will open. In the line that says “opamp2” double Lclick it and edit the line to read LM324. Then close the window and in the toolbar on the far right Lclick on the .op icon and another dialog box will open. In the box type in the line, ‘.inc opamps/LM324.sub’ without the apostrophes and after hitting OK place that spice directive on the schematic. That line will direct LTC to look for the amp or amps .sub circuit file labeled LM324 in the folder it is located. Now in the schematic, right click on the newly placed spice directive, and a box will open up. Hit the open button and a new window with the spice model will open if everything was done correctly. You can close the window and run a simulation. If the amp was correctly labeled no error message will appear.
I know it seems like a long process but if followed precisely, it will take no more than a minute or 2 for the whole thing after a few times. Here is the LM324 model from National Semi:
*//////////////////////////////////////////////////////////////////////
* (C) National Semiconductor, Inc.
* Models developed and under copyright by:
* National Semiconductor, Inc.
*/////////////////////////////////////////////////////////////////////
* Legal Notice: This material is intended for free software support.
* The file may be copied, and distributed; however, reselling the
* material is illegal
*////////////////////////////////////////////////////////////////////
* For ordering or technical information on these models, contact:
* National Semiconductor's Customer Response Center
* 7:00 A.M.--7:00 P.M. U.S. Central Time
* (800) 272-9959
* For Applications support, contact the Internet address:
*
amps-apps@galaxy.nsc.com
*//////////////////////////////////////////////////////////
*LM324 Low Power Quad OPERATIONAL AMPLIFIER MACRO-MODEL
*//////////////////////////////////////////////////////////
*
*connections:
* non-inverting input
* | inverting input
* | | positive power supply
* | | | negative power supply
* | | | | output
* | | | | |
* | | | | |
.SUBCKT LM324 1 2 99 50 28
*
*Features:
*Eliminates need for dual supplies
*Large DC voltage gain = 100dB
*High bandwidth = 1MHz
*Low input offset voltage = 2mV
*Wide supply range = +-1.5V to +-16V
*
*NOTE: Model is for single device only and simulated
* supply current is 1/4 of total device current.
* Output crossover distortion with dual supplies
* is not modeled.
*
****************INPUT STAGE**************
*
IOS 2 1 5N
*^Input offset current
R1 1 3 500K
R2 3 2 500K
I1 99 4 100U
R3 5 50 517
R4 6 50 517
Q1 5 2 4 QX
Q2 6 7 4 QX
*Fp2=1.2 MHz
C4 5 6 128.27P
*
***********COMMON MODE EFFECT***********
*
I2 99 50 75U
*^Quiescent supply current
EOS 7 1 POLY(1) 16 49 2E-3 1
*Input offset voltage.^
R8 99 49 60K
R9 49 50 60K
*
*********OUTPUT VOLTAGE LIMITING********
V2 99 8 1.63
D1 9 8 DX
D2 10 9 DX
V3 10 50 .635
*
**************SECOND STAGE**************
*
EH 99 98 99 49 1
G1 98 9 POLY(1) 5 6 0 9.8772E-4 0 .3459
*Fp1=7.86 Hz
R5 98 9 101.2433MEG
C3 98 9 200P
*
***************POLE STAGE***************
*
*Fp=2 MHz
G3 98 15 9 49 1E-6
R12 98 15 1MEG
C5 98 15 7.9577E-14
*
*********COMMON-MODE ZERO STAGE*********
*
*Fpcm=10 KHz
G4 98 16 3 49 5.6234E-8
L2 98 17 15.9M
R13 17 16 1K
*
**************OUTPUT STAGE**************
*
F6 50 99 POLY(1) V6 300U 1
E1 99 23 99 15 1
R16 24 23 17.5
D5 26 24 DX
V6 26 22 .63V
R17 23 25 17.5
D6 25 27 DX
V7 22 27 .63V
V5 22 21 0.27V
D4 21 15 DX
V4 20 22 0.27V
D3 15 20 DX
L3 22 28 500P
RL3 22 28 100K
*
***************MODELS USED**************
*
.MODEL DX D(IS=1E-15)
.MODEL QX PNP(BF=1.111E3)
*
.ENDS
*$
I have more, but it’s late and I add some other finds in the AM.