Oh I see then I will start the TABLE4 from org 0x400
Then the next instructions in the Table4 followed by 0x401, 402 etc.....

Finally

At one time I saw somewhere telling if the program memory size is less than 2K-words no need to write to PCLATH is this true?

It means if my lines below 2048 then I can directly address to PCL without using PCLATH. In any place from the coding.

Ex: Table1 is in 10th line but I can call from 2000 line?

Thanks a lot.

Maybe some examples will help,

Code:

	movlw	03
	movwf	PCLATH
	movlw	0x45
	movwf	PCL;	will jump to address 0x345

	movlw	07
	movwf	PCLATH
	movlw	0xac
	movwf	PCL;	will jump to address 0x7ac

	movlw	0x0a
	movwf	PCLATH
	movlw	0x67
	movwf	PCL;	will jump to address 0xa67

As you can see PCLATH is simply copied into the high byte of the program counter when you write to PCL.

Note that in the last case it is jumping to an address outside the lower 2K page and so when it returns you must clear PCLATH or subsequent gotos and calls will go to the second bank.

Mike.

Originally Posted by bananasiong

PCLATH can be used to change page. If you're writing to only the same page (under 2 k), you don't need to change page using PCLATH (usually bit 3 and bit 4).
However if you use PCL after the program memory 0xff, you need to write to PCLATH, even you're just using the same page (same 2 k)

Hi thanks a lot guys now I understood how the org 0x003 increments followed by the next instructions. And also I referred to the deassembly listing it was very helpful.

A small quick question to ask.

If I’m using PIC16F628A (2K) if I have a Table I can call it from any location of the memory without writing to PCLATH.
But if the Table has more than 255 lines then of course I have to write to the PCLATH & call the table.

Is this correct?

Thank you to all that contributed to this thread (reputation passed around!) -- I ran into the same problem Tuesday, came looking here for the answer yesterday (this thread just happened to be on page 1!) and fixed it last night (and understand it too!) -- all my tables are working well now (I've taken Nigels advise as well and started placing all my tables in the last page of code space, then started my program code at the beginning... and hope they never meet!

Now -- last night I passed my first CODE page boundary (which messed up my ISR because it was at the end of my code space) -- looks like I've got more reading to do today!

I thought I'd append my question to this thread as I believe it is relevant -- if it should be a new thread, Nigel, please feel free to split it off.

Since reading this thread, I have been able to work with calling tables from different locations (the title of this thread). Now, I have created a macro to handle setting PCLATH for me and would like some opinions on how this is being done. What I mean is, is what I am doing a valid technique, or am I wasting codespace? Obviously, a macro will only save you time/effort, but not codespace as it simply repeats the same code over everywhere the macro is called. Before I forget, here is the macro;

Code:

; macro to set the high bits of PCLATH for a specific table (or call/goto)
; call - _SET_PCLATH	<table/call/goto>
_SET_PCLATH		macro 	table
				movwf	temp					; save W
				movlw	HIGH table				; set the high bits of PCLATH
				movwf	PCLATH					; for the table to be read
				movfw	temp					; restore W
			endm

At first, I setup the above for my tables, but then figured I could use it for calls/gotos as well (just didn't change the attribute name of 'table').

Here is a snippet of code that I just finished "updating", due to my page boundaries. Why I ask these questions is that you can see I am having to call the macro for every call, goto and table to make sure PCLATH is set properly. Some within the module are already set, while others need to be "corrected" after a return from another module... I have included the macro call in ALL of them just to make sure -- and if anything changes in future code, I shouldn't have to worry about where the modules are -- but it does eat up codespace.

Code:

;----------------------------------------------------------------------------------------------
; Boot Information (Model, Version, etc.)
;----------------------------------------------------------------------------------------------

Boot_Info:
		_SET_PCLATH LCD_Clr				;
		call	LCD_Clr
		clrf	count
Boot_Msg:		
		movf	count, w				; put counter value in W
		_SET_PCLATH Boot_Text			;
		call	Boot_Text				; get a character from the text table
		xorlw	0x00					; is it a zero?
		_SET_PCLATH Boot_Version		;
		btfsc	STATUS, Z
		goto	Boot_Version
		_SET_PCLATH LCD_Char			; make sure the page bits are set
		call	LCD_Char
		incf	count, f
		_SET_PCLATH Boot_Msg				
		goto	Boot_Msg

Boot_Version:
		_SET_PCLATH LCD_Line2			; make sure the page bits are set
		call	LCD_Line2
		clrf	count
Boot_Msg2:
		movf	count, w				; put counter value in W
		_SET_PCLATH Boot_Text2			;
		call	Boot_Text2				; get a character from the text table
		xorlw	0x00					; is it a zero?
		_SET_PCLATH Boot_Finish			;
		btfsc	STATUS, Z
		goto	Boot_Finish
		_SET_PCLATH LCD_Char			; make sure the page bits are set
		call	LCD_Char
		incf	count, f
		_SET_PCLATH Boot_Msg2			;
		goto	Boot_Msg2

Boot_Finish:
		_SET_PCLATH Wait1Second			;
		call	Wait1Second				; Wait for 2 seconds
		call 	Wait1Second
		return

I guess I'm really asking -- is there a better way to do this?

TIA!