Need LM317 model for SIMetrix (Spice model?)

Does anyone have the model library that contains variable voltage regulators such as the LM317? Also, how should I model a Brushless motor in this type of simulator.

You should learn how to make your own models. Find the equivalent circuit in the data sheet and build it in the simulator. Your simulator should have a process for converting it to a subcircuit. You have to know how the brushless motor works in order to make a model, I can't help you there.

Thanks for the quick primer. The free version of this software has a limited number of nodes it will simulate before it asks you for some money.

What do you mean by the data sheet. Do you have the URL that shows me the inner workings (or one possible implementation) of the LM317?

I found this: https://www.electro-tech-online.com/custompdfs/2006/01/LM317-DPDF.pdf

This would take me hours construct when I'm pretty sure there are text files that approximate the behavior of this circuit and will work in the free version of this software. Am I wrong to think this?

dinofx said:

I found this: https://www.electro-tech-online.com/custompdfs/2006/01/LM317-DPDF-1.pdf

This would take me hours construct when I'm pretty sure there are text files that approximate the behavior of this circuit and will work in the free version of this software. Am I wrong to think this?

Click to expand...

here is a transistor level spice model from TI, You could also get one from onsemi (where you found the datasheet)

* Voltage regulator TI transistor level model
*
.SUBCKT LM317/TI in adj out
* PEI 08/98 p62
J1 in out 4 JN
Q2 5 5 6 QPL .1
Q3 5 8 9 QNL .2
Q4 8 5 7 QPL .1
Q5 81 8 out QNL .2
Q6 out 81 10 QPL .2
Q7 12 81 13 QNL .2
*Q8 10 5 11 QPL .2
Q8 10A 5 11 QPL .2
Q9 14 12 10 QPL .2
Q10 16 5 17 QPL .2
Q11 16 14 15 QNL .2 OFF
Q12 out 20 16 QPL .2
Q13 in 19 20 QNL .2
Q14 19 5 18 QPL .2
Q15 out 21 19 QPL .2
Q16 21 22 16 QPL .2
Q17 21 out 24 QNL .2
Q18 22 22 16 QPL .2
Q19 22 out 241 QNL .2
Q20 out 25 16 QPL .2
Q21 25 26 out QNL .2
Q22A 35 35 in QPL .2
Q22B 16 35 in QPL .2
Q23 35 16 30 QNL .2
Q24A 27 40 29 QNL .2
Q24B 27 40 28 QNL .2
Q25 in 31 41 QNL 5
Q26 in 41 32 QNL 50
D1 out 4 DZ
D2 33 in DZ
D3 29 34 DZ
R1 in 6 310
R2 in 7 310
R3 in 11 190
R4 in 17 82
R5 in 18 5.6K
R6 4 8 100K
R7 8 81 130
*R8 10 12 12.4K
R8 10A 12 12.4K
R9 9 out 180
R10 13 out 4.1K
R11 14 out 5.8K
R12 15 out 72
R13 20 out 5.1K
R14 adj 24 12K
R15 24 241 2.4K
R16 16 25 6.7K
R17 16 40 12K
R18 30 41 130
R19 16 31 370
R20 26 27 13K
R21 27 40 400
R22 out 41 160
R23 33 34 18K
R24 28 29 160
R25 28 32 3
R26 32 out .1
C1 21 out 30PF
C2 21 adj 30PF
C3 25 26 5PF
CBS1 5 out 2PF
CBS2 35 out 1PF
CBS3 22 out 1PF
.MODEL JN NJF (BETA=1E-4 VTO=-7)
.MODEL DZ D(BV=6.3)
.MODEL QNL NPN (EG=1.22 BF=80 RB=100 CCS=1.5PF TF=.3NS TR=6NS
+ CJE=2PF CJC=1PF VAF=100 IS=1E-22 NF=1.2)
.MODEL QPL PNP (BF=40 RB=20 TF=.6NS TR=10NS CJE=1.5PF CJC=1PF VAF=50
+ IS=1E-22 NF=1.2)
.ENDS LM317/TI

Here is a behavioral model of the same thing.

* Voltage regulator behavioral model
*
.SUBCKT LM317/B IN ADJ OUT
*
* POSITIVE ADJUSTABLE VOLTAGE REGULATOR BEHAVIORAL MODEL
*
JADJ IN ADJ ADJ JADJMOD ;ADJUSTMENT PIN CURRENT
VREF 4 ADJ 1.250
DBK IN 13 DMOD
CBC 13 15 800.0E-12
RBC 15 5 1.000E3
QPASS 13 5 OUT QPASSMOD
RB1 7 6 1
RB2 6 5 128.3
DSC 6 11 DMOD
ESC 11 OUT VALUE={5.646-.6667*V(6,5)*V(13,5)}
DFB 6 12 DMOD
EFB 12 OUT VALUE={8.822-.4024*V(13,5)+5.250E-3*V(13,5)*V(13,5)
+ -.6667*V(13,5)*V(6,5)}
*
EB 7 OUT 8 OUT 6.939
RP 9 8 100
CPZ 10 OUT 3.183E-6
*
DPU 10 OUT DMOD ;POWER-UP CLAMPLING DIODE
RZ 8 10 .1
EP 9 OUT 4 OUT 100
RI OUT 4 100MEG
*
.MODEL QPASSMOD NPN (IS=30F BF=50 VAF=1.500 NF=1.701)
.MODEL JADJMOD NJF (BETA=50.00E-6 VTO=-1)
.MODEL DMOD D (IS=30F N=1.701)
.ENDS

Unless the LM317 is a significant part of your circuit, it is a waste of time to simulate it. I would use a voltage source, perhaps with an output resistor to simulate the output resistance of the LM317. If the LM317 is interacting with your circuit, you should consider re-design.

Thanks, but the purpose of the circuit is to control the 317 so that it produces between 6 and 10 volts at its output. In other words, it isn't hard-wired to produce X volts.

OK, so simulation makes sense, but if it were me, I would read the data sheet and design to accomodate the worst case. It is likely that the model for simulation is not worse case, so the results will be typical and not represent what will happen in production.